# gradient_indice_parabolique_RK4.plt
# -----------------------------------
#
# Avec mes plus vifs remerciements aux developpeurs
# du logiciel gnuplot.
#  
# Dominique RICHIER
# PRAG-HC (en retraite) du Departement Reseaux et Telecommunications
# IUT de NANCY-BRABOIS - Universite de Lorraine.
# ==============================================

reset
set encoding default
set key off
set title "Gradient d'indice optique\nde type parabolique"
set grid
set xlabel "abscisse x (µm)"
set ylabel "indice optique"
n1=1.50
D=0.01
n2=n1*sqrt(1-2*D)
r0 = 25
n(x)= abs(x) <= r0 ? n1*sqrt(1-2*D*(x/r0)*(x/r0)): n2
set samples 256
set xrange [-40 : 40]
set yrange [1.48 : 1.505]
set yzeroaxis lt -1 lw 1
plot n(x) with line lt 7 lw 1
pause -1 "[Entree] pour continuer...]

reset
set encoding default
set key off
set title "Guidage d'un rayon lumineux\
\ndans une fibre optique a gradient d'indice de type parabolique.\
\nCalcul variationnel et integration par la methode de Runge-Kutta RK4,4."
set grid
set xlabel "cote z (µm)"
set ylabel "abscisse x (µm)"
set xrange [ 0 : 1700 ]
set yrange [ -30 : 30 ]
set xzeroaxis lt -1 lw 1
plot "gradient_indice_parabolique_RK4_0.dta" using 1:2 with line lt 7,\
"gradient_indice_parabolique_RK4_1.dta" using 1:2 with line lt 2,\
"gradient_indice_parabolique_RK4_2.dta" using 1:2 with line lt 6,\
-25 lt -1 lw 1 dt 4, 25 lt -1 lw 1 dt 4
pause -1 "[Entree] pour continuer..."

reset
set encoding default
set key off
set title "Guidage d'un rayon lumineux\
\ndans une fibre optique a gradient d'indice de type parabolique.\
\nCalcul variationnel et integration par la methode de Runge-Kutta RK4,4.\
\nEtude dans le plan de phase."
set grid
set xlabel "abscisse x (µm)"
set ylabel "derivee de l'abscisse x\npar rapport a la cote z"
set xrange [ -30 : 30 ]
set yrange [ -0.15 : 0.15 ]
set xzeroaxis lt -1 lw 1
set yzeroaxis lt -1 lw 1
set arrow from -25,-0.15 to -25,0.15 nohead lt -1 lw 1 dt 4
set arrow from 25,-0.15 to 25,0.15  nohead  lt -1 lw 1 dt 4
plot "gradient_indice_parabolique_RK4_0.dta" using 2:3 with line lt 7,\
"gradient_indice_parabolique_RK4_1.dta" using 2:3 with line lt 2,\
"gradient_indice_parabolique_RK4_2.dta" using 2:3 with line lt 6
pause -1 "[Entree] pour terminer..."